為替ロボットの作り方(FXCM用)　ルールの見直し

kawarobo

2005年7月 5日 06:06

　[修正の結果]
修正したところで再度バックテストをしてみます。
資金100,000＄、手数料、スプレッドは0、modelはevery 1 point、Arrows in the chartにチェックを入れます。

結果、矢印の重なりはなくなりました。

とは言え-15,190$と相変わらずマイナスのままですので、これでは使えません。他の通貨で様子を見てみましょう。
ドル円の日足チャートを開き、MAPreGCDCを適用してテストします。
同じように、資金100,000＄、手数料、スプレッドは0、modelはevery 1 point、Arrows in the chartにチェック。
結果、－31,920＄とますます悪い結果に。。パラメーターをいろいろいじってみてもよさそうですが、ここではもう一度チャートの様子を見ることにします。

　[チャートに移動平均を表示]

チャートには売買ポイントを示す矢印が出ていますが、これだけではいまいち分かりません。
MAPreGCDCのルールは、移動平均の長期線と短期線の間に入った時にポジションを取り、GC,DCで閉じるというものでした。
なので、チャート上にも見やすいように移動平均線を表示します。

NavigatorウインドウのIndicatorsからMovingAverageをチャートにドラッグ。バックテストでは長期21、短期5（MaLongPeriod(21),MaShortPeriod(5) ）としていましたので、Period=21, Method=Simple, Applyto=Close, Shift=0で赤色の長期線(21日)を表示、同じようにして今度はPeriod=5、色を白に変えて短期線(5日)を書き出します。

　[ルールの見直し]

これで見やすくなりましたが、かなり「だまし」にやられているようです。しかしそれ以上に、せっかくいいタイミングで入っているときでも、ストップが狭すぎて、損をしているようです。
また、これまではGC、DCで閉じるようにしていましたが、チャートでみると、もう少し粘った方が利益を伸ばせるようにも見えます。
ここをどうにかできないでしょうか。

トレーディングシステム入門という本を見たところ、ディレクショナルスロープ法というやり方が載っていました。
ディレクショナルスロープ法とは、短期と長期、２本の移動平均線を使って、クロスではなく、その傾きをもとにシグナルを出す方法で、2本の移動平均両方が上昇(下降)すれば買い(売り)、短期線の向きが反転したところでポジションを閉じるというものでした。
この方法の一部を拝借することにしましょう。
GCやDCで閉じる代わりに、短期線が反転したところで閉じることにします。

コードは以下のようにしました。

/*[[
	Name := MAPreGCDC
	Author := kawarobo
	Lots := 1.00
	Stop Loss := 100
	Take Profit := 0
	Trailing Stop := 0
]]*/
defines: MaLongPeriod(21),MaShortPeriod(5),type(0);
vars: MaLongCurrent(0),MaLongPrevious(0);
vars: MaShortCurrent(0),MaShortPrevious(0);
vars: Current(0),Previous(0);
vars: Trades(0),TradeType(0),PositionNum(0);
var: cnt(0),openbar(0);

if openbar==bars then Exit;

MaLongCurrent=iMA(MaLongPeriod,MODE_SMA,1);
MaLongPrevious=iMA(MaLongPeriod,MODE_SMA,2);
MaShortCurrent=iMA(MaShortPeriod,MODE_SMA,1);
MaShortPrevious=iMA(MaShortPeriod,MODE_SMA,2);
Current=close[1];
Previous=close[2];

/* 
print("time=",TimeToStr(time[0]));
print("Current=",Current,"Previous=",Previous);
print("MaLongCurrent=",MaLongCurrent,"MaLongPrevious=",MaLongPrevious);
print("MaShortCurrent=",MaShortCurrent,"MaShortPrevious=",MaShortPrevious);
*/

Trades=0;
if TotalTrades>0 then{
	for cnt=1 to TotalTrades
	{
		if OrderValue(cnt,VAL_SYMBOL)==Symbol then
		{
			Trades++; //Trades=Trades+1;
			TradeType=OrderValue(cnt,VAL_TYPE);
			PositionNum=cnt;
		};
	};
};

if Trades<1 then
{
	if Previous< MaShortPrevious and MaShortPrevious < MaLongPrevious
	 & MaShortCurrent < Current  and MaShortCurrent  < MaLongCurrent then
	{ //BUY
		SetOrder(OP_BUY,Lots,Ask,3,Ask-StopLoss*Point,0,Blue);
		openbar=bars;
		Exit;
	};
	if Previous> MaShortPrevious and MaShortPrevious > MaLongPrevious
	 & MaShortCurrent > Current  and MaShortCurrent  > MaLongCurrent then
	{ //SELL
		SetOrder(OP_SELL,Lots,Bid,3,Bid+StopLoss*Point,0,Red);
		openbar=bars;
		Exit;
	};
}
// Trades >= 1
else{
 if type==0 then
 {
	if TradeType==OP_BUY 
	 and MaLongCurrent <= MaShortCurrent
	 and MaShortCurrent < MaShortPrevious then
	{ //close
		CloseOrder(OrderValue(PositionNum,VAL_TICKET),OrderValue(PositionNum,VAL_LOTS),Bid,3,Violet); //*11
		Exit;
	};
	if TradeType==OP_SELL 
	 and MaLongCurrent >= MaShortCurrent
 	 and MaShortCurrent > MaShortPrevious then
	{
		CloseOrder(OrderValue(PositionNum,VAL_TICKET),OrderValue(PositionNum,VAL_LOTS),Ask,3,Violet);
		Exit;
	};
 }else{
 	if TradeType==OP_BUY 
	 and MaShortCurrent < MaShortPrevious then
	{ //close
		CloseOrder(OrderValue(PositionNum,VAL_TICKET),OrderValue(PositionNum,VAL_LOTS),Bid,3,Violet); //*11
		Exit;
	};
	if TradeType==OP_SELL 
 	 and MaShortCurrent > MaShortPrevious then
	{
		CloseOrder(OrderValue(PositionNum,VAL_TICKET),OrderValue(PositionNum,VAL_LOTS),Ask,3,Violet);
		Exit;
	};
 };	 
};
//the end

新たにTypeという定数を用意しました。
Typeが0のときは、ポジションを閉じる時の条件が「短期線が長期線を越えてから、短期線の向きが反転した時点」となります。
Typeを０以外にすると単に「短期線の向きが反転した時点」となって、長期線を越える前でも即、ポジションを閉じてしまうようになります。

ポジションを閉じる条件とは独立して、ストップロスが設定してありますので、一定額の損失が出たところで強制的に損切りされます。
ストップロスの初期値は少し余裕をもたせて100pipsにしてあります。